***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 27, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4465AP   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -2.2		 kp = 10.8		)
.model  dds   d(
+   is = 4.376e-12  	  n = 1.028		   rs = 6.216e-2
+   eg = 1.041	       trs1 = 1.000e-5)
.model  dbody d(
+   is = 4.376e-12  	  n = 1.088		   rs = 7.216e-3
+   eg = 1.041	       trs1 = -1.000e-3
+  cjo = 1.882e-10	  m = 3.394e-1		   vj = 8.239e-1
+   bv = 66		ibv = 250e-6
+ tbv1 = 4.502e-4      tbv2 = -1.050e-7		   tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 4.081e-10	  m = 5.974e-1		   vj = 1.248e-0)
.param
+  cgs = 1.602e-9	cgd = 3.945e-10
+   rd = 5.000e-3	 ra = 5.000e-3
+ trd1 = 1.503e-2      trd2 = 1.065e-4
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (3.00 , 3.00 ),
+ (4.00 , 4.00 ),
+ (4.50 , 4.30 ),
+ (5.00 , 4.50 ),
+ (6.00 , 4.80 ),
+ (7.00 , 5.00 ),
+ (8.00 , 5.20 ),
+ (10.0 , 5.50 ),
+ (12.0 , 5.60 ),
+ (20.0 , 5.80 ),
+ (22.0 , 5.80 ))
egt	  1  2t   value = {7.5e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
